home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / GRAPHICS / RAYTRACING / POVRAY3 / POV301 / povray3 / povscn / level2 / pov / sunsethf < prev    next >
Text File  |  1995-11-08  |  3KB  |  128 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File by Douglas Muir
  3. // Note: Original used 640 x 480 height field.
  4. // This version is scaled down for distribution.
  5. // Requires "fract003.gif" plasma gif for the height field.
  6.  
  7. #version 3.0
  8. global_settings { assumed_gamma 2.2 }
  9.  
  10. #include "shapes.inc"
  11. #include "colors.inc"
  12. #include "textures.inc"
  13.  
  14. camera {
  15.    location <0.0, 80.0, -300.0>
  16.    direction <0.0, 0.0, 1.0>
  17.    up <0.0, 1.0, 0.0>
  18.    right <4/3, 0.0, 0.0>
  19.    look_at <0.0, 30.0, 200.0>
  20. }
  21.  
  22. height_field {
  23.    gif "fract003.gif" 
  24.    water_level 0.4
  25.  
  26.    pigment {
  27.       image_map { gif "fract003.gif" }
  28.       quick_color White
  29.       rotate 90*x
  30.       scale <320.0, 1.0, 200.0>
  31.       translate <0.0, 0.0, -1.0>
  32.    }
  33.  
  34.    scale <320, 256, 200>
  35.    scale <2.0, 0.5, 2.0>
  36.    translate <-160.0, -63.5, -100.0>
  37.    rotate 10*y
  38.    translate <-80.0, 0.0, -30.0>
  39. }
  40.  
  41. // Define the ocean surface 
  42. plane { y, -10.0
  43.    pigment { Aquamarine }
  44.    normal {
  45.       waves 0.06
  46.       frequency 5000.0
  47.       scale 1000.0
  48.    }
  49.    finish {
  50.       ambient 0.1
  51.       diffuse 0.1
  52.       reflection 0.8
  53.    }
  54. }
  55.  
  56. // Put a floor underneath to catch any errant waves from the ripples 
  57. plane { y, -11.0
  58.    pigment { colour red 1.0 green 0.6 }
  59.    finish {
  60.       crand 0.05
  61.       ambient 0.8
  62.       diffuse 0.0
  63.    }
  64. }
  65.  
  66. // Now draw the sky 
  67. sphere { <0.0, 0.0, 0.0>, 3500.0
  68.    pigment {
  69.       onion
  70.       colour_map {
  71.          [0.0 0.6  colour red 1.0 green 0.6 blue 0.0
  72.                    colour red 0.3 green 0.6 blue 0.6]
  73.          [0.6 1.0  colour red 0.3 green 0.6 blue 0.6
  74.                    colour red 0.1 green 0.4 blue 0.6]
  75.       }
  76.       quick_colour red 0.7 green 0.7 blue 1.0
  77.       scale <6000.0, 1700.0, 4000.0>
  78.       translate <-1200.0, 220.0, 2500.0>
  79.    }
  80.    finish {
  81.       ambient 0.8
  82.       diffuse 0.0   /* we don't want clouds casting shadows on the sky */
  83.    }
  84. }
  85.  
  86.  
  87. // Put in a few clouds 
  88. plane { y, 300.0
  89.    pigment {
  90.       bozo
  91.       turbulence 0.5
  92.       colour_map {
  93.          [0.0 0.6   colour red 1.0 green 1.0 blue 1.0 filter 1.0
  94.                     colour red 1.0 green 1.0 blue 1.0 filter 1.0]
  95.          [0.6 0.8   colour red 1.0 green 1.0 blue 1.0 filter 1.0
  96.                     colour red 1.0 green 0.8 blue 0.1]
  97.          [0.8 1.001 colour red 1.0 green 0.8 blue 0.1
  98.                     colour red 0.8 green 0.4 blue 0.2]
  99.       }
  100.       quick_colour red 0.7 green 0.7 blue 1.0
  101.       scale <1000.0, 200.0, 800.0>
  102.    }
  103.    finish {
  104.       ambient 0.7
  105.       diffuse 0.0
  106.    }
  107.  
  108.    translate -450*x
  109.    rotate 6*y
  110. }
  111.  
  112. // Now to cast some light on the subject 
  113. light_source { <-150.0, 250.0, -400.0> colour MediumGoldenrod }
  114.  
  115. // Now to cast some more light on the subject 
  116. light_source {
  117.    <0, 0, 0> colour red 1.0 green 0.7
  118.  
  119.    looks_like {
  120.       sphere { <0.0, 0.0, 0.0>, 190.0
  121.          pigment { colour red 1.0 green 0.6 filter 0.35 }
  122.          finish { ambient 1.0 diffuse 0.0 }
  123.       }
  124.    }
  125.        
  126.    translate <-1300.0, 380.0, 2500.0>
  127. }
  128.